Indhold

# Funktionen TYPOGRAFI (på engelsk: STYLE)

Anvender en typografi på den celle, som indeholder formlen. Efter et angivet tidsrum kan en anden typografi anvendes.

Denne funktion returnerer altid talværdien 0, hvilket gør det muligt at anvende den ved at lægge funktionen TYPOGRAFI til andre funktioner i samme celle uden at ændre værdien.

Funktionen TYPOGRAFI bør ikke anvendes uden tvingende grunde. Dens formål er brug sammen med asynkrone tilføjelsesfunktioner for visuelt at give besked om, at et resultat er tilgængeligt. I næsten alle andre tilfælde er det et bedre valg at anvende betinget formatering.

### Syntaks

TYPOGRAFI("Typografi" [; Tid [; "Typografi2"] ] )

Typografi er navnet på den celletypografi, som skal anvendes på cellen. Typografinavne skal angives i citationstegn og skelner ikke mellem store og små bogstaver.

Tid er et valgfrit tidsrum i sekunder. Når tiden er gået, bliver typografien defineret i Typografi2 anvendt. Lad denne parameter stå tom, hvis du ikke ønsker at typografien skal ændres.

Typografi2 er en valgfri parameter med navn på en celletypografi, som skal anvendes på cellen når tidsrummet angivet af Tid-parameteren er gået. Hvis denne parameter ikke er angivet, bliver celletypografien "Standard" anvendt.

I LibreOffice Calc-funktioner kan parametre markeret som "valgfri" kun udelades, hvis ingen parameter følger. I en funktion med for eksempel fire parametre, hvor de sidste to parametre er markeret som "valgfri", kan du udelade parameter 4 eller parametrene 3 og 4, men du kan ikke udelade parameter 3 alene.

### Eksempler

=10+TYPOGRAFI("God";60;"Neutral")

Skriver værdien 10 i cellen og anvender typografien med navnet "God". Efter 60 sekunder, bliver typografien "Neutral" anvendt.

=A1*A2+TYPOGRAFI(HVIS(AKTUEL()<100;"Dårlig";"God"))

Indskriver resultatet af at multiplicere værdierne i cellerne A1 og A2 og anvender typografien "Dårlig", hvis resultatet er mindre end 100, ellers bliver typografien "God" anvendt. Her bruges funktionen AKTUEL() (på engelsk: CURRENT()) til at skaffe den aktuelt beregnede værdi af funktionen i cellen.

="Total"&T(TYPOGRAFI("Resultat"))

Skriver teksten "Total" i cellen og anvender typografien navngivet "Resultat". Bemærk at dette eksempel håndterer tekstværdier, derfor skal resultatet af TYPOGRAFI-funktionen tilføjes til teksten med operatoren & (i stedet for + i formler med talværdier). Funktionen T() bruges for at forhindre, at tallet "0" tilføjes til den resulterende tekst.

#### Tekniske oplysninger

Denne funktion er IKKE en del af standarden Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Navnerummet er

ORG.OPENOFFICE.STYLE

Relaterede emner

Wiki-side for funktionen TYPOGRAFI (på engelsk: STYLE).

Regnearksfunktioner

Tildeling af format med formel

Funktionen AKTUEL (på engelsk: CURRENT)

T-funktionen (samme navn på engelsk)