  
  [1X5 [33X[0;0Y[5XGAP[105X[101X[1X Computations with [22XO_8^+(5).S_3[122X[101X[1X and [22XO_8^+(2).S_3[122X[101X[1X[133X[101X
  
  [33X[0;0YDate: October 08th, 2006[133X
  
  [33X[0;0YThis  chapter  shows  how  to  construct a representation of the automorphic
  extension  [22XG[122X  of the simple group [22XS = O_8^+(5)[122X by a symmetric group on three
  points,  together  with an embedding of the normalizer [22XH[122X of an [22XO_8^+(2)[122X type
  subgroup of [22XO_8^+(5)[122X.[133X
  
  [33X[0;0YAs  an  application, it is shown that the permutation representation of [22XG[122X on
  the cosets of [22XH[122X has a base of length two. This question arose in [BGS11].[133X
  
  
  [1X5.1 [33X[0;0YOverview[133X[101X
  
  [33X[0;0YLet  [22XS[122X denote the simple group [22XO_8^+(5) ≅[122X P[22XΩ^+(8,5)[122X, that is, the nonabelian
  simple  group  that occurs as a composition factor of the general orthogonal
  group GO[22X^+(8,5)[122X of [22X8 × 8[122X matrices over the field with five elements.[133X
  
  [33X[0;0YThe  outer  automorphism  group of [22XS[122X is isomorphic to the symmetric group on
  four  points.  Let [22XG[122X be an automorphic extension of [22XS[122X by the symmetric group
  on  three  points.  By [Kle87], the group [22XS[122X contains a maximal subgroup [22XM[122X of
  the  type  [22XO_8^+(2)[122X  such  that  the  normalizer  [22XH[122X,  say,  of  [22XM[122X in [22XG[122X is an
  automorphic extension of [22XM[122X by a symmetric group on three points. (In fact, [22XH[122X
  is isomorphic to the full automorphism group of [22XO_8^+(2)[122X.)[133X
  
  [33X[0;0YLet  [22XS.2[122X  and  [22XS.3[122X denote intermediate subgroups between [22XS[122X and [22XG[122X, in which [22XS[122X
  has  the  indices  [22X2[122X and [22X3[122X, respectively. Analogously, let [22XM.2 = H ∩ S.2[122X and
  [22XM.3 = H ∩ S.3[122X.[133X
  
  [33X[0;0YIn  Section [14X5.2[114X,  we use the following approach to construct representations
  of [22XM.2[122X and [22XS.2[122X. By [CCN+85, p. 85], the Weyl group [22XW[122X of type [22XE_8[122X is a double
  cover of [22XM.2[122X, and the reduction of its rational [22X8[122X-dimensional representation
  modulo  [22X5[122X  embeds into the general orthogonal group GO[22X^+(8,5)[122X, which has the
  structure [22X2.O_8^+(5).2^2[122X. Then the actions of GO[22X^+(8,5)[122X and of an isomorphic
  image of [22XW[122X in GO[22X^+(8,5)[122X on [22X1[122X-spaces in the natural module of GO[22X^+(8,5)[122X yield
  [22XM.2[122X  as  a  subgroup  of  (a  supergroup  of)  [22XS.2[122X,  where  both  groups are
  represented as permutation groups on [22XN = 19656[122X points.[133X
  
  [33X[0;0YIn  Section [14X5.3[114X,  first  we  use [5XGAP[105X to compute the automorphism group of [22XM[122X.
  Then  we  take an outer automorphism [22Xα[122X of [22XM[122X, of order three, and extend [22Xα[122X to
  an  automorphism  of [22XS[122X. Concretely, we compute the images of generating sets
  of  [22XS[122X  and [22XM[122X under [22Xα[122X and [22Xα^2[122X. This yields permutation representations of [22XS.3[122X
  and its subgroup [22XM.3[122X on [22X3 N = 58968[122X points.[133X
  
  [33X[0;0YIn Section [14X5.4[114X, we put the above information together, in order to construct
  permutation representations of [22XG[122X and [22XM[122X, on [22X3 N[122X points.[133X
  
  [33X[0;0YAs  an  application,  it  is  shown  in  Section [14X5.5[114X  that  the  permutation
  representation  of  [22XG[122X  on  the  cosets  of  [22XH[122X has a base of length two; this
  question arose in [BGS11].[133X
  
  [33X[0;0YIn  two appendices, it is discussed how to derive a part of this result from
  the permutation character [22X(1_H^G)_H[122X (see Section [14X5.6[114X), and a file containing
  the data used in the earlier sections is described (see Section [14X5.7[114X).[133X
  
  
  [1X5.2 [33X[0;0YConstructing Representations of [22XM.2[122X[101X[1X and [22XS.2[122X[101X[1X[133X[101X
  
  
  [1X5.2-1 [33X[0;0YA Matrix Representation of the Weyl Group of Type [22XE_8[122X[101X[1X[133X[101X
  
  [33X[0;0YFollowing  the  recipe  listed  in [CCN+85,  p.  85,  Section  Weyl], we can
  generate  the Weyl group [22XW[122X of type [22XE_8[122X as a group of rational [22X8 × 8[122X matrices
  generated by the reflections in the vectors[133X
  
  
  [24X[33X[0;6Y(± 1/2, ± 1/2, 0, 0, 0, 0, 0, 0)[133X[124X
  
  [33X[0;0Yplus  the  vectors  obtained  from  these by permuting the coordinates, plus
  those those vectors of the form[133X
  
  
  [24X[33X[0;6Y( ± 1/2, ± 1/2, ± 1/2, ± 1/2, ± 1/2, ± 1/2, ± 1/2, ± 1/2 )[133X[124X
  
  [33X[0;0Ythat  have  an  even  number of negative signs. (Clearly it is sufficient to
  consider only one vector form a pair [22X± v[122X.)[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xrootvectors:= [];;[127X[104X
    [4X[25Xgap>[125X [27Xfor i in Combinations( [ 1 .. 8 ], 2 ) do[127X[104X
    [4X[25X>[125X [27X     v:= 0 * [ 1 .. 8 ];[127X[104X
    [4X[25X>[125X [27X     v{i}:= [ 1, 1 ];[127X[104X
    [4X[25X>[125X [27X     Add( rootvectors, v );[127X[104X
    [4X[25X>[125X [27X     v:= 0 * [ 1 .. 8 ];[127X[104X
    [4X[25X>[125X [27X     v{i}:= [ 1, -1 ];[127X[104X
    [4X[25X>[125X [27X     Add( rootvectors, v );[127X[104X
    [4X[25X>[125X [27X   od;[127X[104X
    [4X[25Xgap>[125X [27XAppend( rootvectors,[127X[104X
    [4X[25X>[125X [27X     1/2 * Filtered( Tuples( [ -1, 1 ], 8 ),[127X[104X
    [4X[25X>[125X [27X             x -> x[1] = 1 and Number( x, y -> y = 1 ) mod 2 = 0 ) );[127X[104X
    [4X[25Xgap>[125X [27Xwe8:= Group( List( rootvectors, ReflectionMat ) );[127X[104X
    [4X[28X<matrix group with 120 generators>[128X[104X
  [4X[32X[104X
  
  
  [1X5.2-2 [33X[0;0YEmbedding the Weyl group of Type [22XE_8[122X[101X[1X into GO[22X^+(8,5)[122X[101X[1X[133X[101X
  
  [33X[0;0YThe  elements  in the group constructed above respect the symmetric bilinear
  form that is given by the identity matrix.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27XI:= IdentityMat( 8 );;[127X[104X
    [4X[25Xgap>[125X [27XForAll( GeneratorsOfGroup( we8 ), x -> x * TransposedMat(x) = I );[127X[104X
    [4X[28Xtrue[128X[104X
  [4X[32X[104X
  
  [33X[0;0YSo  the  reduction of the matrices modulo [22X5[122X yields a group [22XW^∗[122X of orthogonal
  matrices  w. r. t. the  identity matrix. The group GO[22X^+(8,5)[122X returned by the
  [5XGAP[105X function [2XGO[102X ([14XReference: GO[114X) leaves a different bilinear form invariant.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xlargegroup:= GO(1,8,5);;[127X[104X
    [4X[25Xgap>[125X [27XDisplay( InvariantBilinearForm( largegroup ).matrix );[127X[104X
    [4X[28X . 1 . . . . . .[128X[104X
    [4X[28X 1 . . . . . . .[128X[104X
    [4X[28X . . 2 . . . . .[128X[104X
    [4X[28X . . . 2 . . . .[128X[104X
    [4X[28X . . . . 2 . . .[128X[104X
    [4X[28X . . . . . 2 . .[128X[104X
    [4X[28X . . . . . . 2 .[128X[104X
    [4X[28X . . . . . . . 2[128X[104X
  [4X[32X[104X
  
  [33X[0;0YIn order to conjugate [22XW^∗[122X into this group, we need a [22X2 × 2[122X matrix [22XT[122X over the
  field  with five elements with the property that [22XT T^tr[122X is half of the upper
  left [22X2 × 2[122X matrix in the above matrix.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27XT:= [ [ 1, 2 ], [ 4, 2 ] ] * One( GF(5) );;[127X[104X
    [4X[25Xgap>[125X [27XDisplay( 2 * T * TransposedMat( T ) );[127X[104X
    [4X[28X . 1[128X[104X
    [4X[28X 1 .[128X[104X
    [4X[25Xgap>[125X [27XI:= IdentityMat( 8, GF(5) );;[127X[104X
    [4X[25Xgap>[125X [27XI{ [ 1, 2 ] }{ [ 1, 2 ] }:= T;;[127X[104X
    [4X[25Xgap>[125X [27Xconj:= List( GeneratorsOfGroup( we8 ), x -> I * x * I^-1 );;[127X[104X
    [4X[25Xgap>[125X [27XIsSubset( largegroup, conj );[127X[104X
    [4X[28Xtrue[128X[104X
  [4X[32X[104X
  
  
  [1X5.2-3 [33X[0;0YCompatible Generators of [22XM[122X[101X[1X, [22XM.2[122X[101X[1X, [22XS[122X[101X[1X, and [22XS.2[122X[101X[1X[133X[101X
  
  [33X[0;0YFor  the next computations, we switch from the natural matrix representation
  of  GO[22X^+(8,5)[122X  to  a permutation representation of PGO[22X^+(8,5)[122X, of degree [22XN =
  19656[122X,  which  is  given by the action of GO[22X^+(8,5)[122X on the smallest orbit of
  [22X1[122X-spaces in its natural module.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xorbs:= OrbitsDomain( largegroup, NormedRowVectors( GF(5)^8 ),[127X[104X
    [4X[25X>[125X [27X                        OnLines );;[127X[104X
    [4X[25Xgap>[125X [27XList( orbs, Length );[127X[104X
    [4X[28X[ 39000, 39000, 19656 ][128X[104X
    [4X[25Xgap>[125X [27XN:= Length( orbs[3] );[127X[104X
    [4X[28X19656[128X[104X
    [4X[25Xgap>[125X [27XorbN:= SortedList( orbs[3] );;[127X[104X
    [4X[25Xgap>[125X [27Xlargepermgroup:= Action( largegroup, orbN, OnLines );;[127X[104X
  [4X[32X[104X
  
  [33X[0;0YIn  the same way, permutation representations of the subgroup [22XM.2 ≅[122XSO[22X^+(8,2)[122X
  and  of  its derived subgroup [22XM[122X are obtained. But first we compute a smaller
  generating  set of the simple group [22XM[122X, using a permutation representation on
  [22X120[122X points.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xorbwe8:= SortedList( Orbit( we8, rootvectors[1], OnLines ) );;[127X[104X
    [4X[25Xgap>[125X [27XLength( orbwe8 );[127X[104X
    [4X[28X120[128X[104X
    [4X[25Xgap>[125X [27Xwe8_to_m2:= ActionHomomorphism( we8, orbwe8, OnLines );;[127X[104X
    [4X[25Xgap>[125X [27Xm2_120:= Image( we8_to_m2 );;[127X[104X
    [4X[25Xgap>[125X [27Xm_120:= DerivedSubgroup( m2_120 );;[127X[104X
    [4X[25Xgap>[125X [27Xsml:= SmallGeneratingSet( m_120 );;  Length( sml );[127X[104X
    [4X[28X2[128X[104X
    [4X[25Xgap>[125X [27Xgens_m:= List( sml, x -> PreImagesRepresentative( we8_to_m2, x ) );;[127X[104X
  [4X[32X[104X
  
  [33X[0;0YNow  we compute the actions of [22XM[122X and [22XM.2[122X on the above orbit of length [22XN[122X. For
  generating  [22XM.2[122X,  we choose an element [22Xb_N ∈ M.2 ∖ M[122X, which is obtained from
  the action of a matrix [22Xb ∈ 2.M.2 ∖ 2.M[122X.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xgens_m_N:= List( gens_m,[127X[104X
    [4X[25X>[125X [27X     x -> Permutation( I * x * I^-1, orbN, OnLines ) );;[127X[104X
    [4X[25Xgap>[125X [27Xm_N:= Group( gens_m_N );;[127X[104X
    [4X[25Xgap>[125X [27Xb:= I * we8.1 * I^-1;;[127X[104X
    [4X[25Xgap>[125X [27XDeterminantMat( b );[127X[104X
    [4X[28XZ(5)^2[128X[104X
    [4X[25Xgap>[125X [27Xb_N:= Permutation( b, orbN, OnLines );;[127X[104X
    [4X[25Xgap>[125X [27Xm2_N:= ClosureGroup( m_N, b_N );;[127X[104X
  [4X[32X[104X
  
  [33X[0;0Y(Note that [22XM.2[122X is not contained in PSO[22X^+(8,5)[122X, since the determinant of [22Xb[122X is
  [22X-1[122X in the field with five elements.)[133X
  
  [33X[0;0YThe group [22XS[122X is the derived subgroup of PSO[22X^+(8,5)[122X, and [22XS.2[122X is generated by [22XS[122X
  together with [22Xb_N[122X.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xs_N:= DerivedSubgroup( largepermgroup );;[127X[104X
    [4X[25Xgap>[125X [27Xs2_N:= ClosureGroup( s_N, b_N );;[127X[104X
  [4X[32X[104X
  
  
  [1X5.3 [33X[0;0YConstructing Representations of [22XM.3[122X[101X[1X and [22XS.3[122X[101X[1X[133X[101X
  
  
  [1X5.3-1 [33X[0;0YThe Action of [22XM.3[122X[101X[1X on [22XM[122X[101X[1X[133X[101X
  
  [33X[0;0YLet  [22Xα[122X be an automorphism of [22XM[122X, of order three. Then a representation of the
  semidirect product [22XM.3[122X of [22XM[122X by [22X⟨ α ⟩[122X can be constructed as follows.[133X
  
  [33X[0;0YIf  [22XM[122X  is  given  by  a matrix representation then we map [22Xg ∈ M[122X to the block
  diagonal matrix[133X
  
                            ⌈ g             ⌉
                            |   g^α         |
                            ⌊       g^(α^2) ⌋,
  
  [33X[0;0Yand we represent [22Xα[122X by the block permutation matrix[133X
  
                            ⌈     I ⌉
                            | I     |
                            ⌊   I   ⌋,
  
  [33X[0;0Ywhere [22XI[122X is the identity element in [22XM[122X.[133X
  
  [33X[0;0YWe  need  the action of [22Xα[122X on [22XM[122X. More precisely, we need images of the chosen
  generators of [22XM[122X under [22Xα[122X and [22Xα^2[122X.[133X
  
  [33X[0;0YThe  group  [22XM[122X  is  small  enough  for asking [5XGAP[105X to compute its automorphism
  group,  which  is  isomorphic with [22XO^+_8(2).S_3[122X; for that, we use the degree
  [22X120[122X permutation representation constructed in Section [14X5.2-3[114X.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xaut_m:= AutomorphismGroup( m_120 );;[127X[104X
  [4X[32X[104X
  
  [33X[0;0YWe pick an outer automorphism [22Xα[122X of order three.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xnice_aut_m:= NiceMonomorphism( aut_m );;[127X[104X
    [4X[25Xgap>[125X [27Xder:= DerivedSubgroup( Image( nice_aut_m ) );;[127X[104X
    [4X[25Xgap>[125X [27Xder2:= DerivedSubgroup( der );;[127X[104X
    [4X[25Xgap>[125X [27Xrepeat x:= Random( der );[127X[104X
    [4X[25X>[125X [27X     ord:= Order( x );[127X[104X
    [4X[25X>[125X [27X   until ord mod 3 = 0 and ord mod 9 <> 0 and not x in der2;[127X[104X
    [4X[25Xgap>[125X [27Xx:= x^( ord / 3 );;[127X[104X
    [4X[25Xgap>[125X [27Xalpha_120:= PreImagesRepresentative( nice_aut_m, x );;[127X[104X
  [4X[32X[104X
  
  [33X[0;0YNext  we  compute  the images of the generators [10Xsml[110X under [22Xα[122X and [22Xα^2[122X, and the
  corresponding elements in the action of [22XM[122X on [22XN[122X points.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xsml_alpha:= List( sml, x -> Image( alpha_120, x ) );;[127X[104X
    [4X[25Xgap>[125X [27Xsml_alpha_2:= List( sml_alpha, x -> Image( alpha_120, x ) );;[127X[104X
    [4X[25Xgap>[125X [27Xgens_m_alpha:= List( sml_alpha,[127X[104X
    [4X[25X>[125X [27X                    x -> PreImagesRepresentative( we8_to_m2, x ) );;[127X[104X
    [4X[25Xgap>[125X [27Xgens_m_alpha_2:= List( sml_alpha_2,[127X[104X
    [4X[25X>[125X [27X                      x -> PreImagesRepresentative( we8_to_m2, x ) );;[127X[104X
    [4X[25Xgap>[125X [27Xgens_m_N_alpha:= List( gens_m_alpha,[127X[104X
    [4X[25X>[125X [27X     x -> Permutation( I * x * I^-1, orbN, OnLines ) );;[127X[104X
    [4X[25Xgap>[125X [27Xgens_m_N_alpha_2:= List( gens_m_alpha_2,[127X[104X
    [4X[25X>[125X [27X     x -> Permutation( I * x * I^-1, orbN, OnLines ) );;[127X[104X
  [4X[32X[104X
  
  [33X[0;0YFinally,  we use the construction descibed in the beginning of this section,
  and obtain a permutation representation of [22XM.3[122X on [22X3 N = 58968[122X points.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xalpha_3N:= PermList( Concatenation( [ [ 1 .. N ] + 2*N,[127X[104X
    [4X[25X>[125X [27X                                         [ 1 .. N ],[127X[104X
    [4X[25X>[125X [27X                                         [ 1 .. N ] + N ] ) );;[127X[104X
    [4X[25Xgap>[125X [27Xgens_m_3N:= List( [ 1 .. Length( gens_m_N ) ],[127X[104X
    [4X[25X>[125X [27X     i -> gens_m_N[i] *[127X[104X
    [4X[25X>[125X [27X          ( gens_m_N_alpha[i]^alpha_3N ) *[127X[104X
    [4X[25X>[125X [27X          ( gens_m_N_alpha_2[i]^(alpha_3N^2) ) );;[127X[104X
    [4X[25Xgap>[125X [27Xm_3N:= Group( gens_m_3N );;[127X[104X
    [4X[25Xgap>[125X [27Xm3_3N:= ClosureGroup( m_3N, alpha_3N );;[127X[104X
  [4X[32X[104X
  
  
  [1X5.3-2 [33X[0;0YThe Action of [22XS.3[122X[101X[1X on [22XS[122X[101X[1X[133X[101X
  
  [33X[0;0YOur  approach  is  to  extend  the  automorphism [22Xα[122X of [22XM[122X to [22XS[122X; we can do this
  because  in  the  full  automorphism  group of [22XS[122X, [13Xany[113X [22XO^+_8(2)[122X type subgroup
  extends  to  a  group  of  the type [22XO^+_8(2).3[122X, and this extension lies in a
  subgroup of the type [22XO^+_8(5).3[122X (see [Kle87]).[133X
  
  [33X[0;0YThe  group  [22XM[122X  is  maximal  in  [22XS[122X,  so [22XS[122X is generated by [22XM[122X together with any
  element  [22Xs  ∈  S  ∖ M[122X. Having fixed such an element [22Xs[122X, what we have to is to
  find the images of [22Xs[122X under the automorphisms that extend [22Xα[122X and [22Xα^2[122X.[133X
  
  [33X[0;0YFor  that,  we  first choose [22Xx ∈ M[122X such that [22XC_S(x)[122X is a small group that is
  not  contained  in [22XM[122X. Then we choose [22Xs ∈ C_S(x) ∖ M[122X, and using that [22Xs^α[122X must
  lie  in  [22XC_S(C_M(s)^α)[122X,  we then check which elements of this small subgroup
  can be the desired image.[133X
  
  [33X[0;0YEach  element [22Xx[122X of order nine in [22XM[122X has a root [22Xs[122X of order [22X63[122X in [22XS[122X, and [22XC_S(x)[122X
  has  order  [22X189[122X.  For suitable such [22Xx[122X, exactly one element [22Xy ∈ C_S(C_M(s)^α)[122X
  has  order  [22X63[122X and satisfies the necessary conditions that the orders of the
  products of [22Xs[122X and the generators of [22XM[122X are equal to the orders of the product
  of [22Xy[122X and the images of these generators under [22Xα[122X. In other words, we have [22Xs^α
  = y[122X.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xalpha:= GroupHomomorphismByImagesNC( m_N, m_N,[127X[104X
    [4X[25X>[125X [27X               gens_m_N, gens_m_N_alpha );;[127X[104X
    [4X[25Xgap>[125X [27XCheapTestForHomomorphism:= function( gens, genimages, x, cand )[127X[104X
    [4X[25X>[125X [27X       return Order( x ) = Order( cand ) and[127X[104X
    [4X[25X>[125X [27X              ForAll( [ 1 .. Length( gens ) ],[127X[104X
    [4X[25X>[125X [27X           i -> Order( gens[i] * x ) = Order( genimages[i] * cand ) );[127X[104X
    [4X[25X>[125X [27Xend;;[127X[104X
    [4X[25Xgap>[125X [27Xrepeat[127X[104X
    [4X[25X>[125X [27X     repeat[127X[104X
    [4X[25X>[125X [27X       x:= Random( m_N );[127X[104X
    [4X[25X>[125X [27X     until Order( x ) = 9;[127X[104X
    [4X[25X>[125X [27X     c_s:= Centralizer( s_N, x );[127X[104X
    [4X[25X>[125X [27X     repeat[127X[104X
    [4X[25X>[125X [27X       s:= Random( c_s );[127X[104X
    [4X[25X>[125X [27X     until Order( s ) = 63;[127X[104X
    [4X[25X>[125X [27X     c_m_alpha:= Images( alpha, Centralizer( m_N, s ) );[127X[104X
    [4X[25X>[125X [27X     good:= Filtered( Elements( Centralizer( s_N, c_m_alpha ) ),[127X[104X
    [4X[25X>[125X [27X              x -> CheapTestForHomomorphism( gens_m_N,[127X[104X
    [4X[25X>[125X [27X                     gens_m_N_alpha, s, x ) );[127X[104X
    [4X[25X>[125X [27X   until Length( good ) = 1;[127X[104X
    [4X[25Xgap>[125X [27Xs_alpha:= good[1];;[127X[104X
    [4X[25Xgap>[125X [27Xc_m_alpha_2:= Images( alpha, c_m_alpha );;[127X[104X
    [4X[25Xgap>[125X [27Xgood:= Filtered( Elements( Centralizer( s_N, c_m_alpha_2 ) ),[127X[104X
    [4X[25X>[125X [27X     x -> CheapTestForHomomorphism( gens_m_N_alpha, gens_m_N_alpha_2,[127X[104X
    [4X[25X>[125X [27X                                    s_alpha, x ) );;[127X[104X
    [4X[25Xgap>[125X [27Xs_alpha_2:= good[1];;[127X[104X
  [4X[32X[104X
  
  [33X[0;0YUsing  the notation of the previous section, this means that the permutation
  representation  of  [22XM.3[122X on [22X3 N[122X points can be extended to [22XS.3[122X by choosing the
  permutation corresponding to the block diagonal matrix[133X
  
                            ⌈ s             ⌉
                            |   s^α         |
                            ⌊       s^(α^2) ⌋,
  
  [33X[0;0Yas an additional generator.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xouter:= s * ( s_alpha^alpha_3N ) * ( s_alpha_2^(alpha_3N^2) );;[127X[104X
    [4X[25Xgap>[125X [27Xs3_3N:= ClosureGroup( m3_3N, outer );;[127X[104X
  [4X[32X[104X
  
  [33X[0;0Y(And  of course we have [22XS = ⟨ M, s ⟩[122X, which yields generators for [22XS[122X that are
  compatible with those of [22XM[122X.)[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xs_3N:= ClosureGroup( m_3N, outer );;[127X[104X
  [4X[32X[104X
  
  
  [1X5.4 [33X[0;0YConstructing Compatible Generators of [22XH[122X[101X[1X and [22XG[122X[101X[1X[133X[101X
  
  [33X[0;0YAfter  having  constructed  compatible  representations  of [22XM.2[122X and [22XG.2[122X on [22XN[122X
  points  (see  Section [14X5.2-3[114X)  and  of  [22XM.3[122X  and  [22XS.3[122X  on  [22X3  N[122X  points  (see
  Section [14X5.3-2[114X),  the  last construction step is to find a permutation on [22X3 N[122X
  points with the following properties:[133X
  
  [30X    [33X[0;6YThe  induced  automorphism  [22Xβ[122X  of  [22XM[122X  extends  to  [22XM.3[122X  such  that the
        automorphism [22Xα[122X of [22XM[122X is inverted, modulo inner automorphisms of [22XM[122X.[133X
  
  [30X    [33X[0;6YThe  action  on  the first [22XN[122X points coincides with that of the element
        [22Xb_N ∈ M.2 ∖ M[122X that was constructed in Section [14X5.2-3[114X.[133X
  
  [33X[0;0YUsing  the  notation  of  the  previous  sections, we represent [22Xβ[122X by a block
  matrix[133X
  
                            ⌈ b         ⌉
                            |       b d |
                            ⌊   b g     ⌋,
  
  [33X[0;0Ywhere  [22Xb[122X describes the action of [22Xβ[122X on [22XM[122X (on [22XN[122X points), [22Xg[122X describes the inner
  automorphism  [22Xγ[122X  of  [22XM[122X that is defined by the condition [22Xβ α = α^2 β γ[122X, and [22Xd[122X
  describes [22Xγ γ^α[122X.[133X
  
  [33X[0;0YSo  we  compute an element in [22XM[122X that induces the conjugation automorphism [22Xγ[122X,
  and  its image under [22Xα[122X. We do this in the representation of [22XM[122X on [22X120[122X points,
  and  carry  over  the  result  to  the  representation  on [22XN[122X points, via the
  rational  matrix  representation;  this  approach  had  been used already in
  Section [14X5.2-3[114X.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xb_120:= Permutation( we8.1, orbwe8, OnLines );;[127X[104X
    [4X[25Xgap>[125X [27Xg_120:= RepresentativeAction( m_120,[127X[104X
    [4X[25X>[125X [27X               List( sml_alpha_2, x -> x^b_120 ),[127X[104X
    [4X[25X>[125X [27X               List( sml, x -> (x^b_120)^alpha_120 ), OnTuples );;[127X[104X
    [4X[25Xgap>[125X [27Xg_120_alpha:= g_120^alpha_120;;[127X[104X
    [4X[25Xgap>[125X [27Xg_N:= Permutation( I * PreImagesRepresentative( we8_to_m2, g_120 )[127X[104X
    [4X[25X>[125X [27X                        * I^-1, orbN, OnLines );;[127X[104X
    [4X[25Xgap>[125X [27Xg_N_alpha:= Permutation( I * PreImagesRepresentative( we8_to_m2,[127X[104X
    [4X[25X>[125X [27X                 g_120_alpha ) * I^-1, orbN, OnLines );;[127X[104X
    [4X[25Xgap>[125X [27Xinv:= PermList( Concatenation([127X[104X
    [4X[25X>[125X [27X                     ListPerm( b_N ),[127X[104X
    [4X[25X>[125X [27X                     ListPerm( b_N * g_N ) + 2*N,[127X[104X
    [4X[25X>[125X [27X                     ListPerm( b_N * g_N * g_N_alpha ) + N ) );;[127X[104X
  [4X[32X[104X
  
  [33X[0;0YSo we have constructed compatible generators for [22XH[122X and [22XG[122X.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xh:= ClosureGroup( m3_3N, inv );;[127X[104X
    [4X[25Xgap>[125X [27Xg:= ClosureGroup( s3_3N, inv );;[127X[104X
  [4X[32X[104X
  
  
  [1X5.5 [33X[0;0YApplication: Regular Orbits of [22XH[122X[101X[1X on [22XG/H[122X[101X[1X[133X[101X
  
  [33X[0;0YWe  want  to  show  that  [22XH[122X  has regular orbits on the right cosets [22XG/H[122X. The
  stabilizer  in  [22XH[122X  of the coset [22XH g[122X is [22XH ∩ H^g[122X, so we compute that there are
  elements [22Xs ∈ S[122X with the property [22X|H ∩ H^s| = 1[122X.[133X
  
  [33X[0;0Y(Of  course this implies that also in the permutation representations of the
  subgroups [22XS[122X, [22XS.2[122X, and [22XS.3[122X of [22XG[122X on the cosets of the intersection with [22XH[122X, the
  point stabilizers have regular orbits.)[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xrepeat[127X[104X
    [4X[25X>[125X [27X     conj:= Random( s_3N );[127X[104X
    [4X[25X>[125X [27X     inter:= Intersection( h, h^conj );[127X[104X
    [4X[25X>[125X [27X   until Size( inter ) = 1;[127X[104X
  [4X[32X[104X
  
  [33X[0;0YEventually  [5XGAP[105X will return from this loop, so there are elements [22Xs[122X with the
  required property.[133X
  
  [33X[0;0Y(Computing  one  such  intersection  takes  about  six  minutes on a 2.5 GHz
  Pentium 4, so one may have to be a bit patient.)[133X
  
  
  [1X5.6 [33X[0;0YAppendix: The Permutation Character [22X(1_H^G)_H[122X[101X[1X[133X[101X
  
  [33X[0;0YAs an alternative to the computation of [22X|H ∩ H^s|[122X for suitable [22Xs ∈ S[122X, we can
  try   to  derive  information  from  the  permutation  character  [22X(1_H^G)_H[122X.
  Unfortunately,  there  seems  to  be  no  easy way to prove the existence of
  regular [22XH[122X-orbits on [22XG/H[122X (cf. Section [14X5.5[114X) only by means of this character.[133X
  
  [33X[0;0YHowever,  it is not difficult to show that regular orbits of [22XM[122X, [22XM.2[122X, and [22XM.3[122X
  exist. For that, we compute [22X(1_H^G)_H[122X, by computing class representatives of
  [22XH[122X, their centralizer orders in [22XG[122X, and the class fusion of [22XH[122X-classes in [22XG[122X.[133X
  
  [33X[0;0YWe  want  to  compute  the  class  representatives  in  a  small permutation
  representation  of [22XH[122X; this could be done using the degree [22X360[122X representation
  that was implicitly constructed above, but it is technically easier to use a
  degree   [22X405[122X   representation   that  is  obtained  from  the  degree  [22X58968[122X
  representation  by  the  action  of [22XH[122X on blocks in an orbit of length [22X22680[122X.
  (One     could     get     this     also     using    the    [5XGAP[105X    function
  [2XSmallerDegreePermutationRepresentation[102X                           ([14XReference:
  SmallerDegreePermutationRepresentation[114X).)[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xorbs:= Orbits( h, MovedPoints( h ) );;[127X[104X
    [4X[25Xgap>[125X [27XList( orbs, Length );[127X[104X
    [4X[28X[ 22680, 36288 ][128X[104X
    [4X[25Xgap>[125X [27Xorb:= orbs[1];;[127X[104X
    [4X[25Xgap>[125X [27Xbl:= Blocks( h, orb );;  Length( bl[1] );[127X[104X
    [4X[28X2[128X[104X
    [4X[25Xgap>[125X [27Xactbl:= Action( h, bl, OnSets );;[127X[104X
    [4X[25Xgap>[125X [27Xbll:= Blocks( actbl, MovedPoints( actbl ) );;  Length( bll );  [127X[104X
    [4X[28X405[128X[104X
    [4X[25Xgap>[125X [27Xoneblock:= Union( bl{ bll[1] } );;[127X[104X
    [4X[25Xgap>[125X [27Xorb:= SortedList( Orbit( h, oneblock, OnSets ) );;[127X[104X
    [4X[25Xgap>[125X [27Xacthom:= ActionHomomorphism( h, orb, OnSets );;[127X[104X
    [4X[25Xgap>[125X [27Xccl:= ConjugacyClasses( Image( acthom ) );;[127X[104X
    [4X[25Xgap>[125X [27Xreps:= List( ccl, x -> PreImagesRepresentative( acthom,[127X[104X
    [4X[25X>[125X [27X                              Representative( x ) ) );;[127X[104X
  [4X[32X[104X
  
  [33X[0;0YThen we carry back class representatives to the degree [22X58968[122X representation,
  and compute the class fusion and the centralizer orders in [22XG[122X.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xreps:= List( ccl, x -> PreImagesRepresentative( acthom,[127X[104X
    [4X[25X>[125X [27X                              Representative( x ) ) );;[127X[104X
    [4X[25Xgap>[125X [27Xfusion:= [];;[127X[104X
    [4X[25Xgap>[125X [27Xcentralizers:= [];;[127X[104X
    [4X[25Xgap>[125X [27Xfusreps:= [];;[127X[104X
    [4X[25Xgap>[125X [27Xfor i in [ 1 .. Length( reps ) ] do[127X[104X
    [4X[25X>[125X [27X     found:= false;[127X[104X
    [4X[25X>[125X [27X     cen:= Size( Centralizer( g, reps[i] ) );[127X[104X
    [4X[25X>[125X [27X     for j in [ 1 .. Length( fusreps ) ] do[127X[104X
    [4X[25X>[125X [27X       if cen = centralizers[j] and[127X[104X
    [4X[25X>[125X [27X          IsConjugate( g, fusreps[j], reps[i] ) then[127X[104X
    [4X[25X>[125X [27X         fusion[i]:= j;[127X[104X
    [4X[25X>[125X [27X         found:= true;[127X[104X
    [4X[25X>[125X [27X         break;[127X[104X
    [4X[25X>[125X [27X       fi;[127X[104X
    [4X[25X>[125X [27X     od;[127X[104X
    [4X[25X>[125X [27X     if not found then[127X[104X
    [4X[25X>[125X [27X       Add( fusreps, reps[i] );[127X[104X
    [4X[25X>[125X [27X       Add( fusion, Length( fusreps ) );[127X[104X
    [4X[25X>[125X [27X       Add( centralizers, cen );[127X[104X
    [4X[25X>[125X [27X     fi;[127X[104X
    [4X[25X>[125X [27X   od;[127X[104X
  [4X[32X[104X
  
  [33X[0;0YNext we compute the permutation character values, using the formula[133X
  
  
  [24X[33X[0;6Y(1_H)^G(g) = (|C_G(g)| ∑_h |h^H|) /|H| ,[133X[124X
  
  [33X[0;0Ywhere  the  summation  runs  over  class  representatives  [22Xh  ∈  H[122X  that are
  [22XG[122X-conjugate to [22Xg[122X.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xpi:= 0 * [ 1 .. Length( fusreps ) ];;[127X[104X
    [4X[25Xgap>[125X [27Xfor i in [ 1 .. Length( ccl ) ] do[127X[104X
    [4X[25X>[125X [27X     pi[ fusion[i] ]:= pi[ fusion[i] ] + centralizers[ fusion[i] ] *[127X[104X
    [4X[25X>[125X [27X                                             Size( ccl[i] );[127X[104X
    [4X[25X>[125X [27X   od;[127X[104X
    [4X[25Xgap>[125X [27Xpi:= pi{ fusion } / Size( h );;[127X[104X
  [4X[32X[104X
  
  [33X[0;0YIn  order  to write the permutation character w.r.t. the ordering of classes
  in    the    [5XGAP[105X    character    table,    we    use    the   [5XGAP[105X   function
  [2XCompatibleConjugacyClasses[102X ([14XReference: CompatibleConjugacyClasses[114X).[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xtblh:= CharacterTable( "O8+(2).S3" );;[127X[104X
    [4X[25Xgap>[125X [27Xmap:= CompatibleConjugacyClasses( Image( acthom ), ccl, tblh );;[127X[104X
    [4X[25Xgap>[125X [27Xpi:= pi{ map }; [127X[104X
    [4X[28X[ 51162109375, 69375, 1259375, 69375, 568750, 1750, 4000, 375, 135, [128X[104X
    [4X[28X  975, 135, 625, 150, 650, 30, 72, 80, 72, 27, 27, 3, 7, 25, 30, 6, [128X[104X
    [4X[28X  12, 25, 484375, 1750, 375, 375, 30, 40, 15, 15, 15, 6, 6, 3, 3, 3, [128X[104X
    [4X[28X  157421875, 121875, 4875, 475, 75, 3875, 475, 13000, 1750, 300, 400, [128X[104X
    [4X[28X  30, 60, 15, 15, 15, 125, 10, 30, 4, 8, 6, 9, 7, 5, 6, 5 ][128X[104X
  [4X[32X[104X
  
  [33X[0;0YNow  we  consider  the restrictions of this permutation character to [22XM[122X, [22XM.2[122X,
  and [22XM.3[122X. Note that [22X(1_H^G)_M = (1_M^S)_M[122X, [22X(1_H^G)_M.2 = (1_M.2^S.2)_M.2[122X, and
  [22X(1_H^G)_M.3 = (1_M.3^S.3)_M.3[122X.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xtblm2:= CharacterTable( "O8+(2).2" );;[127X[104X
    [4X[25Xgap>[125X [27Xtblm3:= CharacterTable( "O8+(2).3" );;[127X[104X
    [4X[25Xgap>[125X [27Xtblm:= CharacterTable( "O8+(2)" );;[127X[104X
    [4X[25Xgap>[125X [27Xpi_m2:= pi{ GetFusionMap( tblm2, tblh ) };;[127X[104X
    [4X[25Xgap>[125X [27Xpi_m3:= pi{ GetFusionMap( tblm3, tblh ) };;[127X[104X
    [4X[25Xgap>[125X [27Xpi_m:= pi_m3{ GetFusionMap( tblm, tblm3 ) };;[127X[104X
  [4X[32X[104X
  
  [33X[0;0YThe   permutation   character   [22X(1_M^S)_M[122X  decomposes  into  [22X483[122X  transitive
  permutation  characters,  and  regular [22XM[122X-orbits on [22XS/M[122X correspond to regular
  constituents  in  this  decomposition.  If  there  is  no regular transitive
  constituent in [22X(1_M^S)_M[122X then the largest degree of a transitive constituent
  is  [22X|M|/2[122X;  but  then  the  degree of [22X1_M^S[122X is less than [22X483 |M|/2[122X, which is
  smaller than [22X[S:M][122X.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xn:= ScalarProduct( tblm, pi_m, TrivialCharacter( tblm ) );[127X[104X
    [4X[28X483[128X[104X
    [4X[25Xgap>[125X [27Xn * Size( tblm ) / 2;[127X[104X
    [4X[28X42065049600[128X[104X
    [4X[25Xgap>[125X [27Xpi[1];[127X[104X
    [4X[28X51162109375[128X[104X
  [4X[32X[104X
  
  [33X[0;0YFor  the case of [22XM.2 < S.2[122X, this argument turns out to be not sufficient. So
  we first compute a lower bound on the number of regular [22XM[122X-orbits on [22XS/M[122X. For
  involutions  [22Xg  ∈  M[122X,  the  number  of  transitive constituents [22X1_⟨ g ⟩^M[122X in
  [22X(1_M^S)_M[122X  is  at  most  the  integral part of [22X1_M^S(g) / 1_⟨ g ⟩^M(g) = 2 ⋅
  1_M^S(g)  /  |C_M(g)|[122X;  from this we compute that there are at most [22X208[122X such
  constituents.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xinv:= Filtered( [ 1 .. NrConjugacyClasses( tblm ) ],[127X[104X
    [4X[25X>[125X [27X             i -> OrdersClassRepresentatives( tblm )[i] = 2 );[127X[104X
    [4X[28X[ 2, 3, 4, 5, 6 ][128X[104X
    [4X[25Xgap>[125X [27Xn2:= List( inv,[127X[104X
    [4X[25X>[125X [27X          i -> Int( 2 * pi_m[i] / SizesCentralizers( tblm )[i] ) );[127X[104X
    [4X[28X[ 1, 54, 54, 54, 45 ][128X[104X
    [4X[25Xgap>[125X [27XSum( n2 );[127X[104X
    [4X[28X208[128X[104X
  [4X[32X[104X
  
  [33X[0;0YAs a consequence, [22XM[122X has at least [22X148[122X regular orbits on [22XS/M[122X.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27XFirst( [ 1 .. 483 ],                                           [127X[104X
    [4X[25X>[125X [27X     i -> i * Size( tblm ) + 208 * Size( tblm ) / 2[127X[104X
    [4X[25X>[125X [27X          + ( 483 - i - 208 - 1 ) * Size( tblm ) / 3 + 1 >= pi[1] );[127X[104X
    [4X[28X148[128X[104X
  [4X[32X[104X
  
  [33X[0;0YNow  we  consider  the action of [22XM.2[122X on [22XS.2/M.2[122X. If [22XM.2[122X has no regular orbit
  then  the  [22X148[122X  regular  orbits  of  [22XM[122X  must  arise  from the restriction of
  transitive  constituents  [22X1_U^M.2[122X  to  [22XM[122X with [22X|U| = 2[122X and such that [22XU[122X is not
  contained  in  [22XM[122X.  (This  follows  from  the  fact that the restriction of a
  transitive constituent of [22X(1_M.2^S.2)_M.2[122X to [22XM[122X is either itself a transitive
  constituent  of  [22X(1_M^S)_M[122X  or  the sum of two such constituents; the latter
  case occurs if and only if the point stabilizer is contained in [22XM[122X.) However,
  the number of these constituents is at most [22X134[122X.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xinv:= Filtered( [ 1 .. NrConjugacyClasses( tblm2 ) ],[127X[104X
    [4X[25X>[125X [27X             i -> OrdersClassRepresentatives( tblm2 )[i] = 2 and[127X[104X
    [4X[25X>[125X [27X                  not i in ClassPositionsOfDerivedSubgroup( tblm2 ) );[127X[104X
    [4X[28X[ 41, 42 ][128X[104X
    [4X[25Xgap>[125X [27Xn2:= List( inv,[127X[104X
    [4X[25X>[125X [27X          i -> Int( 2 * pi_m2[i] / SizesCentralizers( tblm2 )[i] ) );[127X[104X
    [4X[28X[ 108, 26 ][128X[104X
    [4X[25Xgap>[125X [27XSum( n2 );[127X[104X
    [4X[28X134[128X[104X
  [4X[32X[104X
  
  [33X[0;0YFinally,  we  consider  the  action  of  [22XM.3[122X  on  [22XS.3/M.3[122X.  We  compute that
  [22X(1_M.3^S.3)_M.3[122X  has [22X205[122X transitive constituents, and at most [22X69[122X of them can
  be  induced  from subgroups of order two. This is already sufficient to show
  that there must be regular constituents.[133X
  
  [4X[32X  Example  [32X[104X
    [4X[25Xgap>[125X [27Xn:= ScalarProduct( tblm3, pi_m3, TrivialCharacter( tblm3 ) );[127X[104X
    [4X[28X205[128X[104X
    [4X[25Xgap>[125X [27Xinv:= Filtered( [ 1 .. NrConjugacyClasses( tblm3 ) ],[127X[104X
    [4X[25X>[125X [27X             i -> OrdersClassRepresentatives( tblm3 )[i] = 2 );[127X[104X
    [4X[28X[ 2, 3, 4 ][128X[104X
    [4X[25Xgap>[125X [27Xn2:= List( inv,[127X[104X
    [4X[25X>[125X [27X          i -> Int( 2 * pi_m3[i] / SizesCentralizers( tblm3 )[i] ) );[127X[104X
    [4X[28X[ 0, 54, 15 ][128X[104X
    [4X[25Xgap>[125X [27XSum( n2 );[127X[104X
    [4X[28X69[128X[104X
    [4X[25Xgap>[125X [27X69 * Size( tblm3 ) / 2 + ( n - 69 - 1 ) * Size( tblm3 ) / 3 + 1;[127X[104X
    [4X[28X41542502401[128X[104X
    [4X[25Xgap>[125X [27Xpi[1];[127X[104X
    [4X[28X51162109375[128X[104X
  [4X[32X[104X
  
  
  [1X5.7 [33X[0;0YAppendix: The Data File[133X[101X
  
  [33X[0;0YThe file [11Xo8p2s3_o8p5s3.g[111X that can be found at[133X
  
  [33X[0;0Y[7Xhttp://www.math.rwth-aachen.de/~Thomas.Breuer/ctbllib/data/o8p2s3_o8p5s3.g[107X[133X
  
  [33X[0;0Ycontains  the  relevant data used in the above computations. This covers the
  representations for the groups and the permutation character of [22XO^+_8(2).S_3[122X
  computed in Section [14X5.6[114X.[133X
  
  [33X[0;0YReading  the file into [5XGAP[105X will define a global variable [10Xo8p2s3_o8p5s3_data[110X,
  a record with the following components.[133X
  
  [8X[10Xpi[110X[8X[108X
        [33X[0;6Ythe list of values of the permutation character of [22XG = O^+_8(5).S_3[122X on
        the  cosets  of  its  subgroup  [22XH  =  O^+_8(2).S_3[122X,  restricted  to [22XH[122X,
        corresponding  to  the ordering of classes in the character table of [22XH[122X
        in  the  [5XGAP[105X  Character  Table  Library (this table has the [2XIdentifier[102X
        ([14XReference: Identifier for tables of marks[114X) value [10X"O8+(2).3.2"[110X),[133X
  
  [8X[10Xdim8Q[110X[8X[108X
        [33X[0;6Ya  record  with  generators  for  [22X2.M[122X and [22X2.M.2[122X, matrices of dimension
        eight over the Rationals,[133X
  
  [8X[10Xdeg120[110X[8X[108X
        [33X[0;6Ya record with generators for [22XM[122X and [22XM.2[122X, permutations of degree [22X120[122X,[133X
  
  [8X[10Xdeg360[110X[8X[108X
        [33X[0;6Ya  record  with  generators  for  [22XM[122X,  [22XM.2[122X, [22XM.3[122X, and [22XH[122X, permutations of
        degree [22X360[122X,[133X
  
  [8X[10Xdim8f5[110X[8X[108X
        [33X[0;6Ya  record  with generators for [22X2.M[122X, [22X2.M.2[122X, [22X2.S[122X, and [22X2.S.2[122X, matrices of
        dimension eight over the field with five elements,[133X
  
  [8X[10Xdeg19656[110X[8X[108X
        [33X[0;6Ya  record  with  generators  for  [22XM[122X,  [22XM.2[122X, [22XS[122X, and [22XS.2[122X, permutations of
        degree [22X19656[122X,[133X
  
  [8X[10Xdeg58968[110X[8X[108X
        [33X[0;6Ya  record  with  generators  for  [22XM[122X,  [22XM.2[122X, [22XM.3[122X, [22XH[122X, [22XS[122X, [22XS.2[122X, [22XS.3[122X, and [22XG[122X,
        permutations of degree [22X58968[122X,[133X
  
  [8X[10Xseed405[110X[8X[108X
        [33X[0;6Ya   block  whose  [22XH[122X-orbit  in  the  representation  on  [22X58968[122X  points,
        w.r.t. the  action [2XOnSets[102X ([14XReference: OnSets[114X), yields a representation
        of [22XH[122X on [22X405[122X points.[133X
  
  [33X[0;0YFor each of the permutation representations, we have (where applicable)[133X
  
        [22XM[122X     [22X≅[122X   [22X⟨ a_1, a_2 ⟩[122X,            
        [22XM.2[122X   [22X≅[122X   [22X⟨ a_1, a_2, b ⟩[122X,         
        [22XM.3[122X   [22X≅[122X   [22X⟨ a_1, a_2, t ⟩[122X,         
        [22XH[122X     [22X≅[122X   [22X⟨ a_1, a_2, t, b ⟩[122X,      
        [22XS[122X     [22X≅[122X   [22X⟨ a_1, a_2, c ⟩[122X,         
        [22XS.2[122X   [22X≅[122X   [22X⟨ a_1, a_2, c, b ⟩[122X,      
        [22XS.3[122X   [22X≅[122X   [22X⟨ a_1, a_2, c, t ⟩[122X,      
        [22XG[122X     [22X≅[122X   [22X⟨ a_1, a_2, c, t, b ⟩[122X,   
  
  [33X[0;0Ywhere  [22Xa_1,  a_2, b, t, c[122X are the values of the record components [10Xa1[110X, [10Xa2[110X, [10Xb[110X,
  [10Xt[110X, and [10Xc[110X.[133X
  
  [33X[0;0YAnalogously, for the matrix representations, we have (where applicable)[133X
  
        [22X2.M[122X     [22X≅[122X   [22X⟨ a_1, a_2 ⟩[122X,         
        [22X2.M.2[122X   [22X≅[122X   [22X⟨ a_1, a_2, b ⟩[122X,      
        [22X2.S[122X     [22X≅[122X   [22X⟨ a_1, a_2, c ⟩[122X,      
        [22X2.S.2[122X   [22X≅[122X   [22X⟨ a_1, a_2, c, b ⟩[122X,   
  
  [33X[0;0YAdditional components are used for deriving the representations from initial
  data, as in the constructions in the previous sections.[133X
  
  [33X[0;0YFor example, most of the permutations needed arise as the induced actions of
  matrices  on  orbits  of vectors; these orbits are computed when the file is
  read, and are then stored in the components [10Xorb120[110X and [10Xorb19656[110X.[133X
  
  [33X[0;0YThe  file [11Xo8p2s3_o8p5s3.g[111X does not contain the generators explicitly, but it
  is  self-contained  in  the sense that only a few [5XGAP[105X functions are actually
  needed  to  produce  the  data;  for  example, it should not be difficult to
  translate  the  contents  of  the  file  into the language of other computer
  algebra systems.[133X
  
  [33X[0;0YAdvantages  of this way to store the data are that the relations between the
  representations  become  explicit,  and  also that only very little space is
  needed to describe the representations –the size of the file is less than [22X10[122X
  kB,  whereas  storing  (explicitly)  one of the permutations on [22X58968[122X points
  requires already about [22X350[122X kB.[133X
  
