project(aaroniartsaoutput)

set(aaroniartsaoutput_SOURCES
	aaroniartsaoutput.cpp
	aaroniartsaoutputplugin.cpp
    aaroniartsaoutputsettings.cpp
    aaroniartsaoutputwebapiadapter.cpp
    aaroniartsaoutputworker.cpp
)

set(aaroniartsaoutput_HEADERS
	aaroniartsaoutput.h
	aaroniartsaoutputplugin.h
    aaroniartsaoutputsettings.h
    aaroniartsaoutputwebapiadapter.h
    aaroniartsaoutputworker.h
)

include_directories(
        ${CMAKE_SOURCE_DIR}/swagger/sdrangel/code/qt5/client
)

if(NOT SERVER_MODE)
    set(aaroniartsaoutput_SOURCES
        ${aaroniartsaoutput_SOURCES}
        aaroniartsaoutputgui.cpp
        aaroniartsaoutputgui.ui
    )
    set(aaroniartsaoutput_HEADERS
        ${aaroniartsaoutput_HEADERS}
        aaroniartsaoutputgui.h
    )

    set(TARGET_NAME ${PLUGINS_PREFIX}outputaaroniartsa)
    set(TARGET_LIB "Qt::Widgets")
    set(TARGET_LIB_GUI "sdrgui")
    set(INSTALL_FOLDER ${INSTALL_PLUGINS_DIR})
else()
    set(TARGET_NAME ${PLUGINSSRV_PREFIX}outputaaroniartsasrv)
    set(TARGET_LIB "")
    set(TARGET_LIB_GUI "")
    set(INSTALL_FOLDER ${INSTALL_PLUGINSSRV_DIR})
endif()

if(NOT Qt6_FOUND)
    add_library(${TARGET_NAME} ${aaroniartsaoutput_SOURCES})
else()
    qt_add_plugin(${TARGET_NAME} CLASS_NAME AaroniaRTSAOutputPlugin)
    target_sources(${TARGET_NAME} PRIVATE ${aaroniartsaoutput_SOURCES})
endif()

if(NOT BUILD_SHARED_LIBS)
    set_property(GLOBAL APPEND PROPERTY STATIC_PLUGINS_PROPERTY ${TARGET_NAME})
endif()

target_link_libraries(${TARGET_NAME} PRIVATE
    Qt::Core
    ${TARGET_LIB}
	sdrbase
	${TARGET_LIB_GUI}
    swagger
)

install(TARGETS ${TARGET_NAME} DESTINATION ${INSTALL_FOLDER})

# Install debug symbols
if (WIN32)
    install(FILES $<TARGET_PROPERTY:${TARGET_NAME},RUNTIME_OUTPUT_DIRECTORY>/${TARGET_NAME}stripped.pdb CONFIGURATIONS Release DESTINATION ${INSTALL_FOLDER} RENAME ${TARGET_NAME}.pdb )
    install(FILES $<TARGET_PDB_FILE:${TARGET_NAME}> CONFIGURATIONS Debug RelWithDebInfo DESTINATION ${INSTALL_FOLDER} )
endif()
